/*
 *  Disc library for discs with varying thickness around the circumference
 *  Copyright (C) 2019  Alicia <<email hidden>>
 *
 *  This program is free software: you can redistribute it and/or modify
 *  it under the terms of the GNU Affero General Public License as published by
 *  the Free Software Foundation, either version 3 of the License, or
 *  (at your option) any later version.
 *
 *  This program is distributed in the hope that it will be useful,
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *  GNU Affero General Public License for more details.
 *
 *  You should have received a copy of the GNU Affero General Public License
 *  along with this program.  If not, see <http://www.gnu.org/licenses/>.
*/

// TODO: Handle overhangs
// TODO: Fix centered steepinclines

function sum(v,x=0)=(len(v)==1?x+v[0]:sum([for(i=[1:len(v)-1])v[i]],x+v[0]));
function subvectors(v,x=0)=concat(v[x],(x+1<len(v))?subvectors(v,x+1):[]);

function discfaces1(i,len)=[
  [((i+1)%len)+2, i+2+len, i+2],
  [((i+1)%len)+2, ((i+1)%len)+2+len, i+2+len]
];

// When the next face is lower but on the same X
function discfaces2(i,len)=[
  [i+2+len, i+2, ((i+2)%len)+2+len], // Left
  [((i+2)%len)+2+len, ((i+1)%len)+2+len, i+2+len], // Top/right
  [((i+2)%len)+2+len, i+2, ((i+2)%len)+2] // Bottom/right
];

// When the previous face is lower but on the same X
function discfaces3(i,len)=[
  [(i+1)%len+2+len, ((len+i-1)%len)+2+len, (i+1)%len+2], // Right
  [((len+i-1)%len)+2+len, ((i+1)%len)+2+len, i+2+len], // Top/left
  [((len+i-1)%len)+2+len, ((len+i-1)%len)+2, (i+1)%len+2] // Bottom/left
];

function steepincline(v1,v2)=(v1[0]%360==v2[0]%360 && v2[1]>v1[1]);

module disc(heights_, diameter=10, subdiv=1, center=false)
{
  heights=[for(i=[0:len(heights_)*subdiv-1])[
           i*360/(len(heights_)*subdiv),
           (heights_[floor(i/subdiv)]*(subdiv-i%subdiv)/subdiv+
            heights_[ceil(i/subdiv)%len(heights_)]*(i%subdiv)/subdiv)
          ]];
  discpolygon(heights, diameter, center=center);
}

module discpolygon(points_, diameter=10, center=false)
{
  centerz=sum([for(i=[0:len(points_)-1])points_[i][1]])/len(points_);
  points=concat([[0,0,center?-centerz/2:0],[0,0,center?centerz/2:centerz]],
    [for(i=[0:len(points_)-1])[ // Bottom
      cos(points_[i][0])*diameter/2,
      sin(points_[i][0])*diameter/2,
      center?-points_[i][1]/2:0]],
    [for(i=[0:len(points_)-1])[ // Top
      cos(points_[i][0])*diameter/2,
      sin(points_[i][0])*diameter/2,
      center?points_[i][1]/2:points_[i][1]]]);
  faces=concat(
    // Bottoms
    [for(i=[0:len(points_)-1])[i+2,0,((i+1)%len(points_))+2]],
    // Tops
    [for(i=[0:len(points_)-1])[1,i+2+len(points_),((i+1)%len(points_))+2+len(points_)]],
    // Outsides
    subvectors([for(i=[0:len(points_)-1])
      steepincline(points_[(i+2)%len(points_)], points_[(i+1)%len(points_)])?
        discfaces2(i, len(points_)):
        steepincline(points_[(len(points_)+i-1)%len(points_)], points_[(len(points_)+i)%len(points_)])?
          discfaces3(i, len(points_)):
          discfaces1(i, len(points_))
    ]));
  polyhedron(points, faces, convexity=10);
}

disc([10,15,15,20,10,8,6,7], subdiv=10, diameter=20, center=true);
translate([20,0,0])discpolygon([for(i=[0:10:360])[i,5+i/90]]);
translate([-20,0,0])discpolygon([for(i=[0:10:360])[i,9-i/90]]);