/*
 *  PhoneKeyboard, a holder for a bluetooth keyboard and a phone, joining them into a laptop-like format
 *  Copyright (C) 2018  Alicia <<email hidden>>
 *
 *  This program is free software: you can redistribute it and/or modify
 *  it under the terms of the GNU Affero General Public License as published by
 *  the Free Software Foundation, either version 3 of the License, or
 *  (at your option) any later version.
 *
 *  This program is distributed in the hope that it will be useful,
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *  GNU Affero General Public License for more details.
 *
 *  You should have received a copy of the GNU Affero General Public License
 *  along with this program.  If not, see <http://www.gnu.org/licenses/>.
*/

include <config.scad>
use <phonekeyboard.scad>
$fn=$preview?20:90;

// Phone
%cube([phonewidth,phonethickness,phoneheight], center=true);

%translate([0,-7,-phoneheight/2-18.75])base();

module steppingarm()
{
  difference()
  {
    translate([clearance,0,0])hull()
    {
      rotate([0,90,0])cylinder(3.5,(phonethickness+5)/2,(phonethickness+5)/2);
      translate([1.5,0,9])cube([2,phonethickness+5,1], center=true);
    }
    rotate([0,90,0])cylinder(4,5.5+clearance,5.5+clearance, center=true);
  }
  // Step lock
  rotate([-32,0,0])hull()
  {
    translate([0,0,9.5])cube([1,1,2], center=true);
    translate([-6,0,8.5-1])cube([2,1,1.5], center=true);
  }
}

module mirrorall()
{
  children();
  mirror([0,0,1])children();
  mirror([0,1,0])children();
  mirror([0,1,0])mirror([0,0,1])children();
  mirror([1,0,0])children();
  mirror([1,0,0])mirror([0,0,1])children();
  mirror([1,0,0])mirror([0,1,0])children();
}

module chamfercube(size)
{
  for(i=[0:2])
  {
    csize=[i==0?size[0]:2, i==1?size[1]:2, i==2?size[2]:2];
    rot=[i==0?45:0, i==1?45:0, i==2?45:0];
    pos=[i==0?0:size[0]/2-0.25, i==1?0:size[1]/2-0.25, i==2?0:size[2]/2-0.25];
    mirrorall()translate(pos)rotate(rot)cube(csize, center=true);
  }
}

module splittext(string, font, size, halign, split)
{
  if(split) // Split into 3 lines if the phone is too narrow
  {
    for(i=[0:len(string)-1])
    {
      translate([0,(len(string)-1)*3-i*6])text(string[i], font=font, size=size-0.5, halign=halign);
    }
  }else{
    string=str(string[0],string[1],string[2]);
    text(string, font=font, size=size, halign=halign);
  }
}

module phoneholder()
{
  difference() // The actual holder
  {
    translate([0,0,-phoneheight/4-3])cube([phonewidth+5,phonethickness+5,phoneheight/2], center=true);
    // Slot
    translate([0,0,3])cube([phonewidth+clearance,phonethickness+clearance,phoneheight+6+clearance], center=true);
    // Screen window
    hull()
    {
      translate([0,-phonethickness/2,0])cube([phonewidth,0.1,phoneheight], center=true);
      translate([0,-phonethickness/2-2.5,3])cube([phonewidth-6,0.1,phoneheight], center=true);
    }
    translate([0,-phonethickness/2-3,2])cube([phonewidth-4,3,phoneheight], center=true);
    // Branding
    translate([0,(phonethickness+3)/2,-phoneheight/4])rotate([90,0,180])linear_extrude(2)text("PhoneKeyboard", size=(phonewidth<80?phonewidth/10:phonewidth/15), halign="center");
    translate([0,(phonethickness+3)/2,-phoneheight/2.5])rotate([90,0,180])linear_extrude(2)splittext(["© 2018  ","Alicia <<email hidden>>, ","AGPLv3+"], font=":style=bold", size=4, halign="center", split=phonewidth<105); // Bold doesn't look as nice, but helps combat first-layer-squish-induced narrowing
    // Chamfers
    translate([0,0,-phoneheight/4-3])chamfercube([phonewidth+6,phonethickness+6,phoneheight/2+1]);
  }

  translate([35+clearance,0,-phoneheight/2-3-8])steppingarm();
  mirror([1,0,0])translate([35+clearance,0,-phoneheight/2-3-8])steppingarm();
}

rotate([$preview?0:-90,0,0])phoneholder();